b2eecd643c
src/arch/SConscript:
add mmaped_ipr.hh to switch headers
src/arch/sparc/asi.hh:
make ASI_IMPLICT=0 so by default nothing needs to be done
src/arch/sparc/miscregfile.hh:
miscregfile no longer needs to include asi.hh
src/arch/sparc/tlb.cc:
src/arch/sparc/tlb.hh:
implement panic instructions for mmaped ipr reads
src/cpu/simple/atomic.cc:
add check for mmaped iprs and handle them if it exists
src/mem/request.hh:
allocate space in the flags for mmaped iprs. Put in in the first 8 bits so that by default its fast. Move the other flags up 8 bits
--HG--
extra : convert_revision : 31255b0494588c4d06a727fe35241121d741b115
141 lines
4.8 KiB
Python
141 lines
4.8 KiB
Python
# -*- mode:python -*-
|
|
|
|
# Copyright (c) 2006 The Regents of The University of Michigan
|
|
# All rights reserved.
|
|
#
|
|
# Redistribution and use in source and binary forms, with or without
|
|
# modification, are permitted provided that the following conditions are
|
|
# met: redistributions of source code must retain the above copyright
|
|
# notice, this list of conditions and the following disclaimer;
|
|
# redistributions in binary form must reproduce the above copyright
|
|
# notice, this list of conditions and the following disclaimer in the
|
|
# documentation and/or other materials provided with the distribution;
|
|
# neither the name of the copyright holders nor the names of its
|
|
# contributors may be used to endorse or promote products derived from
|
|
# this software without specific prior written permission.
|
|
#
|
|
# THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
|
|
# "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
|
|
# LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
|
|
# A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
|
|
# OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
|
|
# SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
|
|
# LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
|
|
# DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
|
|
# THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
|
|
# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
|
|
# OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
|
|
#
|
|
# Authors: Steve Reinhardt
|
|
|
|
import os.path, sys
|
|
|
|
# Import build environment variable from SConstruct.
|
|
Import('env')
|
|
|
|
# Right now there are no source files immediately in this directory
|
|
sources = []
|
|
|
|
#################################################################
|
|
#
|
|
# ISA "switch header" generation.
|
|
#
|
|
# Auto-generate arch headers that include the right ISA-specific
|
|
# header based on the setting of THE_ISA preprocessor variable.
|
|
#
|
|
#################################################################
|
|
|
|
# List of headers to generate
|
|
isa_switch_hdrs = Split('''
|
|
arguments.hh
|
|
faults.hh
|
|
interrupts.hh
|
|
isa_traits.hh
|
|
kernel_stats.hh
|
|
locked_mem.hh
|
|
mmaped_ipr.hh
|
|
process.hh
|
|
regfile.hh
|
|
remote_gdb.hh
|
|
stacktrace.hh
|
|
syscallreturn.hh
|
|
tlb.hh
|
|
types.hh
|
|
utility.hh
|
|
vtophys.hh
|
|
''')
|
|
|
|
# Set up this directory to support switching headers
|
|
env.make_switching_dir('arch', isa_switch_hdrs, env)
|
|
|
|
#################################################################
|
|
#
|
|
# Include architecture-specific files.
|
|
#
|
|
#################################################################
|
|
|
|
#
|
|
# Build a SCons scanner for ISA files
|
|
#
|
|
import SCons.Scanner
|
|
|
|
isa_scanner = SCons.Scanner.Classic("ISAScan",
|
|
[".isa", ".ISA"],
|
|
"SRCDIR",
|
|
r'^\s*##include\s+"([\w/.-]*)"')
|
|
|
|
env.Append(SCANNERS = isa_scanner)
|
|
|
|
#
|
|
# Now create a Builder object that uses isa_parser.py to generate C++
|
|
# output from the ISA description (*.isa) files.
|
|
#
|
|
|
|
# Convert to File node to fix path
|
|
isa_parser = File('isa_parser.py')
|
|
cpu_models_file = File('../cpu/cpu_models.py')
|
|
|
|
# This sucks in the defintions of the CpuModel objects.
|
|
execfile(cpu_models_file.srcnode().abspath)
|
|
|
|
# Several files are generated from the ISA description.
|
|
# We always get the basic decoder and header file.
|
|
isa_desc_gen_files = Split('decoder.cc decoder.hh')
|
|
# We also get an execute file for each selected CPU model.
|
|
isa_desc_gen_files += [CpuModel.dict[cpu].filename
|
|
for cpu in env['CPU_MODELS']]
|
|
|
|
# Also include the CheckerCPU as one of the models if it is being
|
|
# enabled via command line.
|
|
if env['USE_CHECKER']:
|
|
isa_desc_gen_files += [CpuModel.dict['CheckerCPU'].filename]
|
|
|
|
# The emitter patches up the sources & targets to include the
|
|
# autogenerated files as targets and isa parser itself as a source.
|
|
def isa_desc_emitter(target, source, env):
|
|
return (isa_desc_gen_files, [isa_parser, cpu_models_file] + source)
|
|
|
|
# Pieces are in place, so create the builder.
|
|
python = sys.executable # use same Python binary used to run scons
|
|
|
|
# Also include the CheckerCPU as one of the models if it is being
|
|
# enabled via command line.
|
|
if env['USE_CHECKER']:
|
|
isa_desc_builder = Builder(action=python + ' $SOURCES $TARGET.dir $CPU_MODELS CheckerCPU',
|
|
emitter = isa_desc_emitter)
|
|
else:
|
|
isa_desc_builder = Builder(action=python + ' $SOURCES $TARGET.dir $CPU_MODELS',
|
|
emitter = isa_desc_emitter)
|
|
|
|
env.Append(BUILDERS = { 'ISADesc' : isa_desc_builder })
|
|
|
|
#
|
|
# Now include other ISA-specific sources from the ISA subdirectories.
|
|
#
|
|
|
|
isa = env['TARGET_ISA'] # someday this may be a list of ISAs
|
|
|
|
# Let the target architecture define what additional sources it needs
|
|
sources += SConscript(os.path.join(isa, 'SConscript'), exports = 'env')
|
|
|
|
Return('sources')
|