b7f653dc49
do Bochs breakpoint and spin in bootasm.S. not needed in bootmain too. fix readseg bug (rounding of va). zero segments when memsz > filesz. no need to clear BSS in kernel main. make bootother.S like bootasm.S
91 lines
3 KiB
ArmAsm
91 lines
3 KiB
ArmAsm
#include "asm.h"
|
|
|
|
# Start the first CPU: switch to 32-bit protected mode, jump into C.
|
|
# The BIOS loads this code from the first sector of the hard disk into
|
|
# memory at physical address 0x7c00 and starts executing in real mode
|
|
# with %cs=0 %ip=7c00.
|
|
|
|
.set CSEG32, 0x8 # kernel code segment selector
|
|
.set DSEG32, 0x10 # kernel data segment selector
|
|
.set CR0_PE, 0x1 # protected mode enable flag
|
|
|
|
.code16 # Assemble for 16-bit mode
|
|
.globl start
|
|
start:
|
|
cli # Disable interrupts
|
|
cld # String operations increment
|
|
|
|
# Set up the important data segment registers (DS, ES, SS).
|
|
xorw %ax,%ax # Segment number zero
|
|
movw %ax,%ds # -> Data Segment
|
|
movw %ax,%es # -> Extra Segment
|
|
movw %ax,%ss # -> Stack Segment
|
|
|
|
# Enable A20:
|
|
# For backwards compatibility with the earliest PCs, physical
|
|
# address line 20 is tied low, so that addresses higher than
|
|
# 1MB wrap around to zero by default. This code undoes this.
|
|
seta20.1:
|
|
inb $0x64,%al # Wait for not busy
|
|
testb $0x2,%al
|
|
jnz seta20.1
|
|
|
|
movb $0xd1,%al # 0xd1 -> port 0x64
|
|
outb %al,$0x64
|
|
|
|
seta20.2:
|
|
inb $0x64,%al # Wait for not busy
|
|
testb $0x2,%al
|
|
jnz seta20.2
|
|
|
|
movb $0xdf,%al # 0xdf -> port 0x60
|
|
outb %al,$0x60
|
|
|
|
//PAGEBREAK!
|
|
# Switch from real to protected mode, using a bootstrap GDT
|
|
# and segment translation that makes virtual addresses
|
|
# identical to physical addresses, so that the
|
|
# effective memory map does not change during the switch.
|
|
lgdt gdtdesc
|
|
movl %cr0, %eax
|
|
orl $CR0_PE, %eax
|
|
movl %eax, %cr0
|
|
|
|
# Jump to next instruction, but in 32-bit code segment.
|
|
# Switches processor into 32-bit mode.
|
|
ljmp $CSEG32, $start32
|
|
|
|
.code32 # Assemble for 32-bit mode
|
|
start32:
|
|
# Set up the protected-mode data segment registers
|
|
movw $DSEG32, %ax # Our data segment selector
|
|
movw %ax, %ds # -> DS: Data Segment
|
|
movw %ax, %es # -> ES: Extra Segment
|
|
movw %ax, %fs # -> FS
|
|
movw %ax, %gs # -> GS
|
|
movw %ax, %ss # -> SS: Stack Segment
|
|
|
|
# Set up the stack pointer and call into C.
|
|
movl $start, %esp
|
|
call bootmain
|
|
|
|
# If bootmain returns (it shouldn't), trigger a Bochs
|
|
# breakpoint if running under Bochs, then loop.
|
|
movw $0x8a00, %ax # 0x8a00 -> port 0x8a00
|
|
movw %ax, %dx
|
|
outw %ax, %dx
|
|
movw $0x8e00, %ax # 0x8e00 -> port 0x8a00
|
|
outw %ax, %dx
|
|
spin:
|
|
jmp spin
|
|
|
|
# Bootstrap GDT
|
|
.p2align 2 # force 4 byte alignment
|
|
gdt:
|
|
SEG_NULLASM # null seg
|
|
SEG_ASM(STA_X|STA_R, 0x0, 0xffffffff) # code seg
|
|
SEG_ASM(STA_W, 0x0, 0xffffffff) # data seg
|
|
|
|
gdtdesc:
|
|
.word 0x17 # sizeof(gdt) - 1
|
|
.long gdt # address gdt
|