74 lines
2.7 KiB
ArmAsm
74 lines
2.7 KiB
ArmAsm
#include "asm.h"
|
|
|
|
# Start an Application Processor. This must be placed on a 4KB boundary
|
|
# somewhere in the 1st MB of conventional memory (APBOOTSTRAP). However,
|
|
# due to some shortcuts below it's restricted further to within the 1st
|
|
# 64KB. The AP starts in real-mode, with
|
|
# CS selector set to the startup memory address/16;
|
|
# CS base set to startup memory address;
|
|
# CS limit set to 64KB;
|
|
# CPL and IP set to 0.
|
|
#
|
|
# mp.c causes each non-boot CPU in turn to jump to start.
|
|
# mp.c puts the correct %esp in start-4, and the place to jump
|
|
# to in start-8.
|
|
#
|
|
# This code is identical to bootasm.S except:
|
|
# - it does not need to enable A20
|
|
# - it uses the address at start-4 for the %esp
|
|
# - it jumps to the address at start-8 instead of calling cmain
|
|
|
|
.set PROT_MODE_CSEG, 0x8 # kernel code segment selector
|
|
.set PROT_MODE_DSEG, 0x10 # kernel data segment selector
|
|
.set CR0_PE_ON, 0x1 # protected mode enable flag
|
|
|
|
.globl start
|
|
start:
|
|
.code16 # Assemble for 16-bit mode
|
|
cli # Disable interrupts
|
|
cld # String operations increment
|
|
|
|
# Set up the important data segment registers (DS, ES, SS).
|
|
xorw %ax,%ax # Segment number zero
|
|
movw %ax,%ds # -> Data Segment
|
|
movw %ax,%es # -> Extra Segment
|
|
movw %ax,%ss # -> Stack Segment
|
|
|
|
//PAGEBREAK!
|
|
# Switch from real to protected mode, using a bootstrap GDT
|
|
# and segment translation that makes virtual addresses
|
|
# identical to their physical addresses, so that the
|
|
# effective memory map does not change during the switch.
|
|
lgdt gdtdesc
|
|
movl %cr0, %eax
|
|
orl $CR0_PE_ON, %eax
|
|
movl %eax, %cr0
|
|
|
|
# Jump to next instruction, but in 32-bit code segment.
|
|
# Switches processor into 32-bit mode.
|
|
ljmp $PROT_MODE_CSEG, $protcseg
|
|
|
|
.code32 # Assemble for 32-bit mode
|
|
protcseg:
|
|
# Set up the protected-mode data segment registers
|
|
movw $PROT_MODE_DSEG, %ax # Our data segment selector
|
|
movw %ax, %ds # -> DS: Data Segment
|
|
movw %ax, %es # -> ES: Extra Segment
|
|
movw %ax, %fs # -> FS
|
|
movw %ax, %gs # -> GS
|
|
movw %ax, %ss # -> SS: Stack Segment
|
|
|
|
movl start-4, %esp
|
|
movl start-8, %eax
|
|
jmp *%eax
|
|
|
|
# Bootstrap GDT
|
|
.p2align 2 # force 4 byte alignment
|
|
gdt:
|
|
SEG_NULLASM # null seg
|
|
SEG_ASM(STA_X|STA_R, 0x0, 0xffffffff) # code seg
|
|
SEG_ASM(STA_W, 0x0, 0xffffffff) # data seg
|
|
|
|
gdtdesc:
|
|
.word 0x17 # sizeof(gdt) - 1
|
|
.long gdt # address gdt
|