2fe8fb192f
There is important information about booting non-ack images in docs/UPDATING. ack/aout-format images can't be built any more, and booting clang/ELF-format ones is a little different. Updating to the new boot monitor is recommended. Changes in this commit: . drop boot monitor -> allowing dropping ack support . facility to copy ELF boot files to /boot so that old boot monitor can still boot fairly easily, see UPDATING . no more ack-format libraries -> single-case libraries . some cleanup of OBJECT_FMT, COMPILER_TYPE, etc cases . drop several ack toolchain commands, but not all support commands (e.g. aal is gone but acksize is not yet). . a few libc files moved to netbsd libc dir . new /bin/date as minix date used code in libc/ . test compile fix . harmonize includes . /usr/lib is no longer special: without ack, /usr/lib plays no kind of special bootstrapping role any more and bootstrapping is done exclusively through packages, so releases depend even less on the state of the machine making them now. . rename nbsd_lib* to lib* . reduce mtree
82 lines
2.9 KiB
ArmAsm
82 lines
2.9 KiB
ArmAsm
/* $NetBSD: memccpy.S,v 1.1 2001/02/05 00:17:22 scottr Exp $ */
|
|
|
|
/*
|
|
* Copyright (C) 1999 Scott Reynolds. All rights reserved.
|
|
*
|
|
* Redistribution and use in source and binary forms, with or without
|
|
* modification, are permitted provided that the following conditions
|
|
* are met:
|
|
* 1. Redistributions of source code must retain the above copyright
|
|
* notice, this list of conditions and the following disclaimer.
|
|
* 2. Redistributions in binary form must reproduce the above copyright
|
|
* notice, this list of conditions and the following disclaimer in the
|
|
* documentation and/or other materials provided with the distribution.
|
|
* 3. The name of the author may not be used to endorse or promote products
|
|
* derived from this software without specific prior written permission.
|
|
*
|
|
* THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
|
|
* IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
|
|
* OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
|
|
* IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
|
|
* INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
|
|
* NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
|
|
* DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
|
|
* THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
|
|
* (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
|
|
* THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
|
|
*/
|
|
|
|
#include <machine/asm.h>
|
|
|
|
#if defined(LIBC_SCCS) && !defined(lint)
|
|
RCSID("$NetBSD: memccpy.S,v 1.1 2001/02/05 00:17:22 scottr Exp $")
|
|
#endif /* LIBC_SCCS and not lint */
|
|
|
|
ENTRY(memccpy)
|
|
movl %sp@(16),%d0 | count
|
|
jeq Lmcbail | nothing to do
|
|
|
|
movl %sp@(4),%a0 | a0 = toaddr
|
|
subql #1,%d0 | prepare count for DBcc loop
|
|
movl %sp@(8),%a1 | a1 = fromaddr
|
|
movl %sp@(12),%d1 | d1 = terminator
|
|
jeq Lmcloop | handle ASCII NUL specially
|
|
|
|
movl %d2,%sp@- | save scratch register
|
|
Lmcnzloop:
|
|
movb %a1@+,%d2 | move a byte
|
|
movb %d2,%a0@+
|
|
cmpb %d2,%d1 | found the terminator?
|
|
dbeq %d0,Lmcnzloop | if not, keep transferring,
|
|
jeq Lmcnzdone | otherwise done
|
|
clrw %d0 | check to see if more to do
|
|
subql #1,%d0
|
|
jcc Lmcnzloop | yes, keep going...
|
|
|
|
movl %sp@+,%d2 | restore scratch register
|
|
movql #0,%d0 | no terminator found, return NULL
|
|
#ifdef __SVR4_ABI__
|
|
movl %d0,%a0 | XXX maybe use lea to avoid stall?
|
|
#endif
|
|
rts
|
|
|
|
Lmcloop:
|
|
movb %a1@+,%a0@+ | move a byte; was it NUL?
|
|
dbeq %d0,Lmcloop | if not, keep transferring,
|
|
jeq Lmcdone | otherwise done
|
|
clrw %d0 | check to see if more to do
|
|
subql #1,%d0
|
|
jcc Lmcloop | yes, keep going...
|
|
| Note: %d0 is now -1!
|
|
movql #0,%d0 | no terminator found, return NULL
|
|
Lmcbail:
|
|
#ifdef __SVR4_ABI__
|
|
movl %d0,%a0 | XXX maybe use lea to avoid stall?
|
|
#endif
|
|
rts
|
|
|
|
Lmcnzdone:
|
|
movl %sp@+,%d2 | restore scratch register
|
|
Lmcdone:
|
|
movl %a0,%d0
|
|
rts
|