Initial SCons-based build system. See www.scons.org.
'cd build; scons' will build ALPHA/m5.debug.
Use e.g. 'scons KERNEL/m5.opt' to build other binaries.
Read the comments in build/SConstruct for more details.
base/traceflags.py:
Take basename of generated cc/hh files from command line instead
of hardwiring them. Lets us call the script from a different
directory and still have the files end up in the right place
(e.g. "base/traceflags.py base/traceflags").
--HG--
extra : convert_revision : ee4dbb59040cf07590929275f6c1c01e8d4e00b4
This commit is contained in:
Steve Reinhardt
parent
6083c8280b
commit
b13e28afbb
3 changed files with 675 additions and 2 deletions
384
SConscript
Normal file
384
SConscript
Normal file
|
|
@ -0,0 +1,384 @@
|
|||
# -*- mode:python -*-
|
||||
|
||||
# Copyright (c) 2004 The Regents of The University of Michigan
|
||||
# All rights reserved.
|
||||
#
|
||||
# Redistribution and use in source and binary forms, with or without
|
||||
# modification, are permitted provided that the following conditions are
|
||||
# met: redistributions of source code must retain the above copyright
|
||||
# notice, this list of conditions and the following disclaimer;
|
||||
# redistributions in binary form must reproduce the above copyright
|
||||
# notice, this list of conditions and the following disclaimer in the
|
||||
# documentation and/or other materials provided with the distribution;
|
||||
# neither the name of the copyright holders nor the names of its
|
||||
# contributors may be used to endorse or promote products derived from
|
||||
# this software without specific prior written permission.
|
||||
#
|
||||
# THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
|
||||
# "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
|
||||
# LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
|
||||
# A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
|
||||
# OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
|
||||
# SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
|
||||
# LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
|
||||
# DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
|
||||
# THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
|
||||
# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
|
||||
# OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
|
||||
|
||||
import os
|
||||
import sys
|
||||
|
||||
# This file defines how to build a particular configuration of M5
|
||||
# based on variable settings in the 'env' build environment.
|
||||
|
||||
# Import build environment variable from SConstruct.
|
||||
Import('env')
|
||||
|
||||
###################################################
|
||||
#
|
||||
# Define needed sources.
|
||||
#
|
||||
###################################################
|
||||
|
||||
# Base sources used by all configurations.
|
||||
base_sources = Split('''
|
||||
arch/alpha/decoder.cc
|
||||
arch/alpha/fast_cpu_exec.cc
|
||||
arch/alpha/simple_cpu_exec.cc
|
||||
arch/alpha/full_cpu_exec.cc
|
||||
arch/alpha/faults.cc
|
||||
arch/alpha/isa_traits.cc
|
||||
|
||||
base/circlebuf.cc
|
||||
base/copyright.cc
|
||||
base/cprintf.cc
|
||||
base/fast_alloc.cc
|
||||
base/fifo_buffer.cc
|
||||
base/hostinfo.cc
|
||||
base/hybrid_pred.cc
|
||||
base/inifile.cc
|
||||
base/intmath.cc
|
||||
base/misc.cc
|
||||
base/pollevent.cc
|
||||
base/python.cc
|
||||
base/range.cc
|
||||
base/sat_counter.cc
|
||||
base/socket.cc
|
||||
base/statistics.cc
|
||||
base/str.cc
|
||||
base/time.cc
|
||||
base/trace.cc
|
||||
base/traceflags.cc
|
||||
base/userinfo.cc
|
||||
base/compression/lzss_compression.cc
|
||||
base/loader/aout_object.cc
|
||||
base/loader/ecoff_object.cc
|
||||
base/loader/elf_object.cc
|
||||
base/loader/object_file.cc
|
||||
base/loader/symtab.cc
|
||||
base/stats/events.cc
|
||||
base/stats/python.cc
|
||||
base/stats/statdb.cc
|
||||
base/stats/visit.cc
|
||||
base/stats/text.cc
|
||||
|
||||
cpu/base_cpu.cc
|
||||
cpu/exec_context.cc
|
||||
cpu/exetrace.cc
|
||||
cpu/pc_event.cc
|
||||
cpu/static_inst.cc
|
||||
cpu/fast_cpu/fast_cpu.cc
|
||||
cpu/full_cpu/bpred.cc
|
||||
cpu/full_cpu/commit.cc
|
||||
cpu/full_cpu/create_vector.cc
|
||||
cpu/full_cpu/cv_spec_state.cc
|
||||
cpu/full_cpu/dd_queue.cc
|
||||
cpu/full_cpu/dep_link.cc
|
||||
cpu/full_cpu/dispatch.cc
|
||||
cpu/full_cpu/dyn_inst.cc
|
||||
cpu/full_cpu/execute.cc
|
||||
cpu/full_cpu/fetch.cc
|
||||
cpu/full_cpu/floss_reasons.cc
|
||||
cpu/full_cpu/fu_pool.cc
|
||||
cpu/full_cpu/full_cpu.cc
|
||||
cpu/full_cpu/inst_fifo.cc
|
||||
cpu/full_cpu/instpipe.cc
|
||||
cpu/full_cpu/issue.cc
|
||||
cpu/full_cpu/ls_queue.cc
|
||||
cpu/full_cpu/machine_queue.cc
|
||||
cpu/full_cpu/pipetrace.cc
|
||||
cpu/full_cpu/readyq.cc
|
||||
cpu/full_cpu/reg_info.cc
|
||||
cpu/full_cpu/rob_station.cc
|
||||
cpu/full_cpu/spec_memory.cc
|
||||
cpu/full_cpu/spec_state.cc
|
||||
cpu/full_cpu/storebuffer.cc
|
||||
cpu/full_cpu/writeback.cc
|
||||
cpu/full_cpu/iq/iq_station.cc
|
||||
cpu/full_cpu/iq/iqueue.cc
|
||||
cpu/full_cpu/iq/segmented/chain_info.cc
|
||||
cpu/full_cpu/iq/segmented/chain_wire.cc
|
||||
cpu/full_cpu/iq/segmented/iq_seg.cc
|
||||
cpu/full_cpu/iq/segmented/iq_segmented.cc
|
||||
cpu/full_cpu/iq/segmented/seg_chain.cc
|
||||
cpu/full_cpu/iq/seznec/iq_seznec.cc
|
||||
cpu/full_cpu/iq/standard/iq_standard.cc
|
||||
cpu/sampling_cpu/sampling_cpu.cc
|
||||
cpu/simple_cpu/simple_cpu.cc
|
||||
cpu/trace/reader/mem_trace_reader.cc
|
||||
cpu/trace/reader/ibm_reader.cc
|
||||
cpu/trace/reader/itx_reader.cc
|
||||
cpu/trace/reader/m5_reader.cc
|
||||
|
||||
mem/base_hier.cc
|
||||
mem/base_mem.cc
|
||||
mem/hier_params.cc
|
||||
mem/mem_cmd.cc
|
||||
mem/mem_debug.cc
|
||||
mem/mem_req.cc
|
||||
mem/memory_interface.cc
|
||||
mem/bus/base_interface.cc
|
||||
mem/bus/bus.cc
|
||||
mem/bus/bus_bridge.cc
|
||||
mem/bus/bus_bridge_master.cc
|
||||
mem/bus/bus_bridge_slave.cc
|
||||
mem/bus/bus_interface.cc
|
||||
mem/bus/dma_bus_interface.cc
|
||||
mem/bus/dma_interface.cc
|
||||
mem/bus/master_interface.cc
|
||||
mem/bus/slave_interface.cc
|
||||
mem/cache/base_cache.cc
|
||||
mem/cache/cache.cc
|
||||
mem/cache/cache_builder.cc
|
||||
mem/cache/coherence/coherence_protocol.cc
|
||||
mem/cache/coherence/uni_coherence.cc
|
||||
mem/cache/miss/blocking_buffer.cc
|
||||
mem/cache/miss/miss_queue.cc
|
||||
mem/cache/miss/mshr.cc
|
||||
mem/cache/miss/mshr_queue.cc
|
||||
mem/cache/tags/base_tags.cc
|
||||
mem/cache/tags/cache_tags.cc
|
||||
mem/cache/tags/fa_lru.cc
|
||||
mem/cache/tags/iic.cc
|
||||
mem/cache/tags/lru.cc
|
||||
mem/cache/tags/repl/gen.cc
|
||||
mem/cache/tags/repl/repl.cc
|
||||
mem/functional_mem/functional_memory.cc
|
||||
mem/functional_mem/main_memory.cc
|
||||
mem/timing_mem/base_memory.cc
|
||||
mem/timing_mem/memory_builder.cc
|
||||
mem/timing_mem/simple_mem_bank.cc
|
||||
mem/trace/mem_trace_writer.cc
|
||||
mem/trace/m5_writer.cc
|
||||
|
||||
sim/builder.cc
|
||||
sim/configfile.cc
|
||||
sim/debug.cc
|
||||
sim/eventq.cc
|
||||
sim/main.cc
|
||||
sim/param.cc
|
||||
sim/profile.cc
|
||||
sim/serialize.cc
|
||||
sim/sim_events.cc
|
||||
sim/sim_exit.cc
|
||||
sim/sim_init.cc
|
||||
sim/sim_object.cc
|
||||
sim/stat_context.cc
|
||||
sim/stat_control.cc
|
||||
sim/sw_context.cc
|
||||
sim/trace_context.cc
|
||||
sim/universe.cc
|
||||
''')
|
||||
|
||||
# MySql sources
|
||||
mysql_sources = Split('''
|
||||
base/mysql.cc
|
||||
base/stats/mysql.cc
|
||||
''')
|
||||
|
||||
# Full-system sources
|
||||
full_system_sources = Split('''
|
||||
arch/alpha/alpha_memory.cc
|
||||
arch/alpha/arguments.cc
|
||||
arch/alpha/ev5.cc
|
||||
arch/alpha/osfpal.cc
|
||||
arch/alpha/pseudo_inst.cc
|
||||
arch/alpha/vtophys.cc
|
||||
|
||||
base/inet.cc
|
||||
base/remote_gdb.cc
|
||||
|
||||
cpu/intr_control.cc
|
||||
|
||||
dev/alpha_console.cc
|
||||
dev/baddev.cc
|
||||
dev/simconsole.cc
|
||||
dev/disk_image.cc
|
||||
dev/dma.cc
|
||||
dev/etherdump.cc
|
||||
dev/etherint.cc
|
||||
dev/etherlink.cc
|
||||
dev/etherpkt.cc
|
||||
dev/ethertap.cc
|
||||
dev/ide_ctrl.cc
|
||||
dev/ide_disk.cc
|
||||
dev/io_device.cc
|
||||
dev/ns_gige.cc
|
||||
dev/etherdev.cc
|
||||
dev/pciconfigall.cc
|
||||
dev/pcidev.cc
|
||||
dev/scsi.cc
|
||||
dev/scsi_ctrl.cc
|
||||
dev/scsi_disk.cc
|
||||
dev/scsi_none.cc
|
||||
dev/simple_disk.cc
|
||||
dev/tlaser_clock.cc
|
||||
dev/tlaser_ipi.cc
|
||||
dev/tlaser_mbox.cc
|
||||
dev/tlaser_mc146818.cc
|
||||
dev/tlaser_node.cc
|
||||
dev/tlaser_pcia.cc
|
||||
dev/tlaser_pcidev.cc
|
||||
dev/tlaser_serial.cc
|
||||
dev/turbolaser.cc
|
||||
dev/tsunami.cc
|
||||
dev/tsunami_cchip.cc
|
||||
dev/tsunami_fake.cc
|
||||
dev/tsunami_io.cc
|
||||
dev/tsunami_pchip.cc
|
||||
dev/uart.cc
|
||||
|
||||
kern/kernel_stats.cc
|
||||
kern/system_events.cc
|
||||
kern/linux/linux_events.cc
|
||||
kern/linux/linux_syscalls.cc
|
||||
kern/linux/linux_system.cc
|
||||
kern/tru64/dump_mbuf.cc
|
||||
kern/tru64/printf.cc
|
||||
kern/tru64/tru64_events.cc
|
||||
kern/tru64/tru64_syscalls.cc
|
||||
kern/tru64/tru64_system.cc
|
||||
|
||||
mem/functional_mem/memory_control.cc
|
||||
mem/functional_mem/physical_memory.cc
|
||||
dev/platform.cc
|
||||
|
||||
sim/system.cc
|
||||
''')
|
||||
|
||||
# Syscall emulation (non-full-system) sources
|
||||
syscall_emulation_sources = Split('''
|
||||
arch/alpha/alpha_common_syscall_emul.cc
|
||||
arch/alpha/alpha_linux_process.cc
|
||||
arch/alpha/alpha_tru64_process.cc
|
||||
cpu/memtest/memtest.cc
|
||||
cpu/trace/trace_cpu.cc
|
||||
eio/eio.cc
|
||||
eio/exolex.cc
|
||||
eio/libexo.cc
|
||||
sim/process.cc
|
||||
sim/syscall_emul.cc
|
||||
''')
|
||||
|
||||
# Set up complete list of sources based on configuration.
|
||||
sources = base_sources
|
||||
|
||||
if env['FULL_SYSTEM']:
|
||||
sources += full_system_sources
|
||||
else:
|
||||
sources += syscall_emulation_sources
|
||||
|
||||
if env['USE_MYSQL']:
|
||||
sources += mysql_sources
|
||||
|
||||
###################################################
|
||||
#
|
||||
# Special build rules.
|
||||
#
|
||||
###################################################
|
||||
|
||||
# base/traceflags.{cc,hh} are generated from base/traceflags.py.
|
||||
# $TARGET.base will expand to "<build-dir>/base/traceflags".
|
||||
env.Command(Split('base/traceflags.hh base/traceflags.cc'),
|
||||
'base/traceflags.py',
|
||||
'python $SOURCE $TARGET.base')
|
||||
|
||||
# several files are generated from arch/$TARGET_ISA/isa_desc.
|
||||
env.Command(Split('''arch/alpha/decoder.cc
|
||||
arch/alpha/decoder.hh
|
||||
arch/alpha/fast_cpu_exec.cc
|
||||
arch/alpha/simple_cpu_exec.cc
|
||||
arch/alpha/full_cpu_exec.cc'''),
|
||||
'arch/alpha/isa_desc',
|
||||
'$SRCDIR/arch/isa_parser.py $SOURCE $TARGET.dir arch/alpha')
|
||||
|
||||
|
||||
# 'targetarch' is a symlink to arch/$TARGET_ISA.
|
||||
def link_targetarch(target, source, env):
|
||||
link_target = str(target[0])
|
||||
link_source = env.subst('$SRCDIR/arch/$TARGET_ISA')
|
||||
if not os.path.isdir(link_target):
|
||||
print "symlinking", link_source, "to", link_target
|
||||
try:
|
||||
os.symlink(link_source, link_target)
|
||||
except OSError, desc:
|
||||
print "Error creating symlink %s: %s" % (link_target, desc)
|
||||
sys.exit(-1)
|
||||
|
||||
# Tell SCons to use the link_targetarch function to make 'targetarch'
|
||||
env.Command('targetarch', None, link_targetarch)
|
||||
|
||||
|
||||
# This function adds the specified sources to the given build
|
||||
# environment, and returns a list of all the corresponding SCons
|
||||
# Object nodes (including an extra one for date.cc). We explicitly
|
||||
# add the Object nodes so we can set up special dependencies for
|
||||
# targetarch and date.cc.
|
||||
def make_objs(sources, env):
|
||||
objs = [env.Object(s) for s in sources]
|
||||
# make all objects depend on the targetarch link so it gets made first.
|
||||
env.Depends(objs, 'targetarch')
|
||||
# make date.cc depend on all other objects so it always gets
|
||||
# recompiled whenever anything else does
|
||||
date_obj = env.Object('base/date.cc')
|
||||
env.Depends(date_obj, objs)
|
||||
objs.append(date_obj)
|
||||
return objs
|
||||
|
||||
###################################################
|
||||
#
|
||||
# Define binaries. Each different build type (debug, opt, etc.) gets
|
||||
# a slightly different build environment.
|
||||
#
|
||||
###################################################
|
||||
|
||||
# Include file paths are rooted in this directory. SCons will
|
||||
# automatically expand '.' to refer to both the source directory and
|
||||
# the corresponding build directory to pick up generated include
|
||||
# files.
|
||||
env.Append(CPPPATH='.')
|
||||
|
||||
# Debug binary
|
||||
debug = env.Copy(OBJSUFFIX='.do')
|
||||
debug.Append(CCFLAGS=Split('-g -gstabs+ -O0'))
|
||||
debug.Append(CPPDEFINES='DEBUG')
|
||||
debug.Program(target = 'm5.debug', source = make_objs(sources, debug))
|
||||
|
||||
# Optimized binary
|
||||
opt = env.Copy()
|
||||
opt.Append(CCFLAGS=Split('-g -O5'))
|
||||
opt.Program(target = 'm5.opt', source = make_objs(sources, opt))
|
||||
|
||||
# "Fast" binary
|
||||
fast = env.Copy(OBJSUFFIX='.fo')
|
||||
fast.Append(CCFLAGS=Split('-O5'))
|
||||
fast.Append(CPPDEFINES='NDEBUG')
|
||||
fast.Program(target = 'm5.fast.unstripped', source = make_objs(sources, fast))
|
||||
fast.Command(target = 'm5.fast', source = 'm5.fast.unstripped',
|
||||
action = 'strip $SOURCE -o $TARGET')
|
||||
|
||||
# Profiled binary
|
||||
prof = env.Copy(OBJSUFFIX='.po')
|
||||
prof.Append(CCFLAGS=Split('-O5 -g -pg'), LINKFLAGS='-pg')
|
||||
prof.Program(target = 'm5.prof', source = make_objs(sources, prof))
|
||||
|
|
@ -30,8 +30,15 @@
|
|||
# This file generates the header and source files for the flags
|
||||
# that control the tracing facility.
|
||||
#
|
||||
hhfilename="traceflags.hh"
|
||||
ccfilename="traceflags.cc"
|
||||
|
||||
import sys
|
||||
|
||||
if len(sys.argv) != 2:
|
||||
print "%s: Need argument (basename of cc/hh files)" % sys.argv[0]
|
||||
sys.exit(1)
|
||||
|
||||
hhfilename = sys.argv[1] + '.hh'
|
||||
ccfilename = sys.argv[1] + '.cc'
|
||||
|
||||
#
|
||||
# The list of trace flags that can be used to condition DPRINTFs etc.
|
||||
|
|
|
|||
282
build/SConstruct
Normal file
282
build/SConstruct
Normal file
|
|
@ -0,0 +1,282 @@
|
|||
# -*- mode:python -*-
|
||||
|
||||
# Copyright (c) 2004 The Regents of The University of Michigan
|
||||
# All rights reserved.
|
||||
#
|
||||
# Redistribution and use in source and binary forms, with or without
|
||||
# modification, are permitted provided that the following conditions are
|
||||
# met: redistributions of source code must retain the above copyright
|
||||
# notice, this list of conditions and the following disclaimer;
|
||||
# redistributions in binary form must reproduce the above copyright
|
||||
# notice, this list of conditions and the following disclaimer in the
|
||||
# documentation and/or other materials provided with the distribution;
|
||||
# neither the name of the copyright holders nor the names of its
|
||||
# contributors may be used to endorse or promote products derived from
|
||||
# this software without specific prior written permission.
|
||||
#
|
||||
# THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
|
||||
# "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
|
||||
# LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
|
||||
# A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
|
||||
# OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
|
||||
# SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
|
||||
# LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
|
||||
# DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
|
||||
# THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
|
||||
# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
|
||||
# OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
|
||||
|
||||
###################################################
|
||||
#
|
||||
# SCons top-level build description (SConstruct) file.
|
||||
#
|
||||
# To build M5, you need a directory with three things:
|
||||
# 1. A copy of this file (named SConstruct).
|
||||
# 2. A link named 'm5' to the top of the M5 simulator source tree.
|
||||
# 3. A link named 'ext' to the top of the M5 external source tree.
|
||||
#
|
||||
# Then type 'scons' to build the default configuration (see below), or
|
||||
# 'scons <CONFIG>/<binary>' to build some other configuration (e.g.,
|
||||
# 'KERNEL/m5.opt' for the optimized full-system version).
|
||||
#
|
||||
###################################################
|
||||
|
||||
# Python library imports
|
||||
import sys
|
||||
import os
|
||||
|
||||
# The absolute path to the current directory (where this file lives).
|
||||
ROOT = Dir('.').abspath
|
||||
|
||||
# Paths to the M5 and external source trees (local symlinks).
|
||||
SRCDIR = os.path.join(ROOT, 'm5')
|
||||
EXT_SRCDIR = os.path.join(ROOT, 'ext')
|
||||
|
||||
# Check for 'm5' and 'ext' links, die if they don't exist.
|
||||
if not os.path.isdir(SRCDIR):
|
||||
print "Error: '%s' must be a link to the M5 source tree." % SRCDIR
|
||||
sys.exit(1)
|
||||
|
||||
if not os.path.isdir('ext'):
|
||||
print "Error: '%s' must be a link to the M5 external source tree." \
|
||||
% EXT_SRCDIR
|
||||
sys.exit(1)
|
||||
|
||||
|
||||
###################################################
|
||||
#
|
||||
# Define Configurations
|
||||
#
|
||||
# The build system infers the build options from the subdirectory name
|
||||
# that the simulator is built under. The subdirectory name must be of
|
||||
# the form <CONFIG>[.<OPT>]*, where <CONFIG> is a base configuration
|
||||
# (e.g., ALPHA or KERNEL) and OPT is an option (e.g., MYSQL). The
|
||||
# following code defines the standard configurations and options.
|
||||
# Additional local configurations and options are read from the file
|
||||
# 'local_configs' if it exists.
|
||||
#
|
||||
# Each base configuration or option is defined in two steps: a
|
||||
# function that takes an SCons build environment and modifies it
|
||||
# appropriately for that config or option, and an entry in the
|
||||
# 'configs_map' or 'options_map' dictionary that maps the directory
|
||||
# name string to the function. (The directory names are all upper
|
||||
# case, by convention.)
|
||||
#
|
||||
###################################################
|
||||
|
||||
# Base non-full-system Alpha ISA configuration.
|
||||
def AlphaConfig(env):
|
||||
env.Replace(TARGET_ISA = 'alpha')
|
||||
env.Append(CPPDEFINES = 'SS_COMPATIBLE_FP')
|
||||
|
||||
# Base full-system configuration.
|
||||
def KernelConfig(env):
|
||||
env.Replace(TARGET_ISA = 'alpha')
|
||||
env.Replace(FULL_SYSTEM = True)
|
||||
env.Append(CPPDEFINES = ['FULL_SYSTEM', 'SYSTEM_EV5'])
|
||||
|
||||
# Base configurations map.
|
||||
configs_map = {
|
||||
'ALPHA' : AlphaConfig,
|
||||
'KERNEL' : KernelConfig
|
||||
}
|
||||
|
||||
# Enable detailed full-system binning.
|
||||
def MeasureOpt(env):
|
||||
env.Replace(USE_MYSQL = True)
|
||||
env.Append(CPPDEFINES = 'FS_MEASURE')
|
||||
|
||||
# Enable MySql database output for stats.
|
||||
def MySqlOpt(env):
|
||||
env.Replace(USE_MYSQL = True)
|
||||
|
||||
# Disable FastAlloc object allocation.
|
||||
def NoFastAllocOpt(env):
|
||||
env.Append(CPPDEFINES = 'NO_FAST_ALLOC')
|
||||
|
||||
# Configuration options map.
|
||||
options_map = {
|
||||
'MEASURE' : MeasureOpt,
|
||||
'MYSQL' : MySqlOpt,
|
||||
'NO_FAST_ALLOC' : NoFastAllocOpt
|
||||
}
|
||||
|
||||
# The 'local_configs' file can be used to define additional base
|
||||
# configurations and/or options without changing this file.
|
||||
if os.path.isfile('local_configs'):
|
||||
SConscript('local_configs', exports = ['configs_map', 'options_map'])
|
||||
|
||||
# This function parses a directory name of the form <CONFIG>[.<OPT>]*
|
||||
# and sets up the build environment appropriately. Returns True if
|
||||
# successful, False if the base config or any of the options were not
|
||||
# defined.
|
||||
def set_dir_options(dir, env):
|
||||
parts = dir.split('.')
|
||||
config = parts[0]
|
||||
opts = parts[1:]
|
||||
try:
|
||||
configs_map[config](env)
|
||||
map(lambda opt: options_map[opt](env), opts)
|
||||
return True
|
||||
except KeyError, key:
|
||||
print "Config/option '%s' not found." % key
|
||||
return False
|
||||
|
||||
# Set the default configuration and binary. The default target (if
|
||||
# scons is invoked at the top level with no command-line targets) is
|
||||
# 'ALPHA/m5.debug'. If scons is invoked in a subdirectory with no
|
||||
# command-line targets, the configuration
|
||||
|
||||
###################################################
|
||||
#
|
||||
# Figure out which configurations to set up.
|
||||
#
|
||||
#
|
||||
# It's prohibitive to do all the combinations of base configurations
|
||||
# and options, so we have to infer which ones the user wants.
|
||||
#
|
||||
# 1. If there are command-line targets, the configuration(s) are inferred
|
||||
# from the directories of those targets. If scons was invoked from a
|
||||
# subdirectory (using 'scons -u'), those targets have to be
|
||||
# interpreted relative to that subdirectory.
|
||||
#
|
||||
# 2. If there are no command-line targets, and scons was invoked from a
|
||||
# subdirectory (using 'scons -u'), the configuration is inferred from
|
||||
# the name of the subdirectory.
|
||||
#
|
||||
# 3. If there are no command-line targets and scons was invoked from
|
||||
# the root build directory, a default configuration is used. The
|
||||
# built-in default is ALPHA, but this can be overridden by setting the
|
||||
# M5_DEFAULT_CONFIG shell environment veriable.
|
||||
#
|
||||
# In cases 2 & 3, the specific file target defaults to 'm5.debug', but
|
||||
# this can be overridden by setting the M5_DEFAULT_BINARY shell
|
||||
# environment veriable.
|
||||
#
|
||||
###################################################
|
||||
|
||||
# Find default configuration & binary.
|
||||
default_config = os.environ.get('M5_DEFAULT_CONFIG', 'ALPHA')
|
||||
default_binary = os.environ.get('M5_DEFAULT_BINARY', 'm5.debug')
|
||||
|
||||
# Ask SCons which directory it was invoked from. If you invoke SCons
|
||||
# from a subdirectory you must use the '-u' flag.
|
||||
launch_dir = GetLaunchDir()
|
||||
|
||||
# Build a list 'my_targets' of all the targets relative to ROOT.
|
||||
if launch_dir == ROOT:
|
||||
# invoked from root build dir
|
||||
if len(COMMAND_LINE_TARGETS) != 0:
|
||||
# easy: use specified targets as is
|
||||
my_targets = COMMAND_LINE_TARGETS
|
||||
else:
|
||||
# default target (ALPHA/m5.debug, unless overridden)
|
||||
target = os.path.join(default_config, default_binary)
|
||||
my_targets = [target]
|
||||
Default(target)
|
||||
else:
|
||||
# invoked from subdirectory
|
||||
if not launch_dir.startswith(ROOT):
|
||||
print "Error: launch dir (%s) not a subdirectory of ROOT (%s)!" \
|
||||
(launch_dir, ROOT)
|
||||
sys.exit(1)
|
||||
# make launch_dir relative to ROOT (strip ROOT plus slash off front)
|
||||
launch_dir = launch_dir[len(ROOT)+1:]
|
||||
if len(COMMAND_LINE_TARGETS) != 0:
|
||||
# make specified targets relative to ROOT
|
||||
my_targets = map(lambda x: os.path.join(launch_dir, x),
|
||||
COMMAND_LINE_TARGETS)
|
||||
else:
|
||||
# build default binary (m5.debug, unless overridden) using the
|
||||
# config inferred by the invocation directory (the first
|
||||
# subdirectory after ROOT)
|
||||
target = os.path.join(launch_dir.split('/')[0], default_binary)
|
||||
my_targets = [target]
|
||||
Default(target)
|
||||
|
||||
# Normalize target paths (gets rid of '..' in the middle, etc.)
|
||||
my_targets = map(os.path.normpath, my_targets)
|
||||
|
||||
# Generate a list of the unique configs that the collected targets reference.
|
||||
build_dirs = []
|
||||
for t in my_targets:
|
||||
dir = t.split('/')[0]
|
||||
if dir not in build_dirs:
|
||||
build_dirs.append(dir)
|
||||
|
||||
###################################################
|
||||
#
|
||||
# Set up the default build environment. This environment is copied
|
||||
# and modified according to each selected configuration.
|
||||
#
|
||||
###################################################
|
||||
|
||||
default_env = Environment(ENV = os.environ, # inherit user's enviroment vars
|
||||
ROOT = ROOT,
|
||||
SRCDIR = SRCDIR,
|
||||
EXT_SRCDIR = EXT_SRCDIR,
|
||||
CPPDEFINES = [],
|
||||
FULL_SYSTEM = False,
|
||||
USE_MYSQL = False)
|
||||
|
||||
# M5_EXT is used by isa_parser.py to find the PLY package.
|
||||
default_env.Append(ENV = { 'M5_EXT' : EXT_SRCDIR })
|
||||
|
||||
default_env.Append(CCFLAGS='-pipe')
|
||||
default_env.Append(CCFLAGS='-fno-strict-aliasing')
|
||||
default_env.Append(CCFLAGS=Split('-Wall -Wno-sign-compare -Werror -Wundef'))
|
||||
|
||||
# libelf build is described in its own SConscript file. Using a
|
||||
# dictionary for exports lets us export "default_env" so the
|
||||
# SConscript will see it as "env".
|
||||
default_env.SConscript('m5/libelf/SConscript', exports={'env' : default_env})
|
||||
|
||||
|
||||
###################################################
|
||||
#
|
||||
# Define build environments for selected configurations.
|
||||
#
|
||||
###################################################
|
||||
|
||||
for build_dir in build_dirs:
|
||||
# Make a copy of the default environment to use for this config.
|
||||
env = default_env.Copy()
|
||||
# Modify 'env' according to the build directory config.
|
||||
print "Configuring options for directory '%s'." % build_dir
|
||||
if not set_dir_options(build_dir, env):
|
||||
print "Skipping directory '%s'." % build_dir
|
||||
continue
|
||||
|
||||
# The m5/SConscript file sets up the build rules in 'env' according
|
||||
# to the configured options.
|
||||
SConscript('m5/SConscript', build_dir = build_dir, exports = 'env',
|
||||
duplicate=0)
|
||||
|
||||
|
||||
###################################################
|
||||
#
|
||||
# Let SCons do its thing. At this point SCons will use the defined
|
||||
# build enviornments to build the requested targets.
|
||||
#
|
||||
###################################################
|
||||
|
||||
Loading…
Reference in a new issue